Saxon

In finding variants of the code in https://saxonica.plan.io/issues/5035 I tried to use an array as the container for streamed nodes, not being sure what should and would happen.

Saxon EE 10.5 Java tells me it should be streamable but it has no watch; the code

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="3.0"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:mf="http://example.com/mf"
    exclude-result-prefixes="#all">
    
    <xsl:function name="mf:group-into-sequence-of-arrays" as="array(*)*" visibility="public" streamability="absorbing">
        <xsl:param name="items" as="item()*"/>
        <xsl:param name="chunk-size" as="xs:integer"/>
        <xsl:for-each-group select="$items" group-adjacent="(position() - 1) idiv $chunk-size">
            <xsl:sequence select="array { current-group() }"/>
        </xsl:for-each-group>
    </xsl:function>
    
    <xsl:template match="/*">
        <xsl:copy>
            <xsl:iterate select="mf:group-into-sequence-of-arrays(*, 3)">
                <chunk index="{position()}">
                    <xsl:sequence select="?*"/>
                </chunk>
            </xsl:iterate>
        </xsl:copy>
    </xsl:template>
    
    <xsl:output indent="yes"/>
    
</xsl:stylesheet>

gives

Error in xsl:for-each-group/@select on line 11 column 96 of array-test1.xsl:
  SXST0067  Component cannot be streamed, although it is guaranteed streamable according to
  W3C rules. No watch implemented for CurrentGroupCall
Errors were reported during stylesheet compilation

Then I tried to find in the spec whether an array is supposed to be allowed to contain streamed nodes and https://www.w3.org/TR/xslt-30/#streaming-other-types clearly says:

The rules for creating maps and arrays are designed to ensure that the entries in a map, and the members of an array, cannot contain nodes from a streamed document.

So based on that I guess the code above should not pass the streamability analysis.

Can't find array {}, however, in the formal streamability rules.

Input can be any with at least two levels of elements e.g.

<?xml version="1.0" encoding="utf-8"?>
<root>
    <item>item 01</item>
    <item>item 02</item>
    <item>item 03</item>
    <item>item 04</item>
    <item>item 05</item>
    <item>item 06</item>
    <item>item 07</item>
    <item>item 08</item>
    <item>item 09</item>
    <item>item 10</item>
    <item>item 11</item>
    <item>item 12</item>
    <item>item 13</item>
    <item>item 14</item>
    <item>item 15</item>
    <item>item 16</item>
    <item>item 17</item>
    <item>item 18</item>
    <item>item 19</item>
    <item>item 20</item>
    <item>item 21</item>
    <item>item 22</item>
    <item>item 23</item>
</root>